How do I get my figures into Power BI or Excel?

Power BI and Excel fetch data through Power Query, and both understand the same query, written in the M language. The template below loads your account’s daily rows as a table with suitable column types. After that you refresh it like any other data source.

How to set it up

1. 01In the portal, create a read key under “Exports & AI connections” in “API access”, ideally one just for this file.
2. 02Open the Power Query editor with a blank query: in Excel via “Data > Get Data > From Other Sources > Blank Query”, in Power BI Desktop via “Home > Get data > Blank query”.
3. 03Create the parameter MetrunioKey of type “Text” via “Home > Manage Parameters > New Parameter” and enter your key as its current value.
4. 04Select the blank query, click “Advanced Editor”, replace its contents with the template below and confirm with “Done”.
5. 05If Power Query asks how to access the web content, choose “Anonymous”. The query sends the key itself in the Authorization header, and Power Query only accepts that header with this kind of access.
6. 06Load the table with “Close & Load” in Excel or “Close & Apply” in Power BI.

The template

// Metrunio: daily rows per channel and campaign, the last 30 days up to today.
// The key comes from the parameter MetrunioKey and never appears in the address.
let
    Response = Json.Document(
        Web.Contents(
            "https://api.metrunio.com/v1/data/daily",
            [Headers = [Authorization = "Bearer " & MetrunioKey, #"Accept-Language" = "en"]]
        )
    ),
    Rows = Table.FromRecords(
        Response[data],
        {
            "day", "channelName", "campaignName",
            "attributedConversions", "attributedRevenue", "postViewConversions",
            "unattributedConversions", "unattributedRevenue",
            "clicks", "impressions", "viewableImpressions", "cost"
        },
        MissingField.UseNull
    ),
    Typed = Table.TransformColumnTypes(Rows, {
        {"day", type date}, {"channelName", type text}, {"campaignName", type text},
        {"attributedConversions", type number}, {"attributedRevenue", type number},
        {"postViewConversions", type number}, {"unattributedConversions", type number},
        {"unattributedRevenue", type number}, {"clicks", Int64.Type},
        {"impressions", Int64.Type}, {"viewableImpressions", Int64.Type},
        {"cost", type number}
    }),
    Named = Table.RenameColumns(Typed, {
        {"day", "Day"}, {"channelName", "Channel"}, {"campaignName", "Campaign"},
        {"attributedConversions", "Attributed conversions"},
        {"attributedRevenue", "Attributed revenue"},
        {"postViewConversions", "Post-view conversions"},
        {"unattributedConversions", "Unattributed conversions"},
        {"unattributedRevenue", "Unattributed revenue"},
        {"clicks", "Clicks"}, {"impressions", "Impressions"},
        {"viewableImpressions", "Viewable impressions"}, {"cost", "Cost"}
    })
in
    Named

What the table contains

One row per day, channel and campaign for the last 30 days up to and including today, counted in your account’s time zone. Attributed conversions and attributed revenue follow your account’s default model, like the reports; clicks and impressions are measured. If a row’s cost stays empty, no cost was recorded for it. That is not the same as zero. Unattributed conversions sit in the row without channel and campaign.

Refreshing

• Excel: “Data > Refresh All” fetches the figures again. In the query properties you can have Excel refresh when the file opens.
• Power BI Desktop: “Refresh” on the Home ribbon.
• Power BI service: for scheduled refresh, set the data source credentials to “Anonymous” and tick “Skip test connection”. Otherwise the service tests the connection without the key and gets a refusal.

Adjusting it

• Period and model: in the Web.Contents call, add for example Query = [from = "2026-01-01", model = "linear"] next to Headers. Without an end, the period runs up to today; without a model, your account’s default model applies.
• A query returns at most 50,000 rows. If it needs more, the API refuses instead of dropping rows; a shorter period helps.
• When the API refuses, Power Query shows the status number. 401 means the key is missing, incomplete, revoked or expired. 403 means your plan does not include the read API or the account is not active. 422 means the period has too many rows or a setting is wrong.